TRichView.com

Code: Select all

procedure TdlgNotePreview.PrintToPDF(aContents: TMemoryStream);
var
  i: Integer;
  Metafile: TMetafile;
  RVUnit: TRVUnits;
begin
  srve.Update; //srve is ScaleRichViewComponent
  gtPDFEngine1.UserStream := aContents;
  gtPDFEngine1.BeginDoc;
  if (gtPDFEngine1.EngineStatus <> esStarted) then
    Exit;
  RVUnit := srve.UnitsProgram; //Get the current value
  srve.UnitsProgram := rvuPixels; //Change DBSRichviewEdit to pixels for PDF Conversion

  for i := 1 to srve.PageCount do
  begin
    if i > 1 then
      gtPDFEngine1.NewPage;
    Metafile := MakePageMetafile(i, Round(srve.PageProperty.PageWidth), Round(srve.PageProperty.PageHeight));
    try
      gtPDFEngine1.Canvas.Draw(0, 0, Metafile);
    finally
      Metafile.Free;
    end;
  end;
  gtPDFEngine1.EndDoc;
  srve.UnitsProgram := RVUnit; //Change back to the previous value before converted to pixels  
end;

function TdlgNotePreview.MakePageMetafile(aPageNo, aWidth, aHeight: Integer): TMetafile;
var
  savTextDraw: Boolean;
begin
  savTextDraw := ScaleRichViewTextDrawAlwaysUseGlyphs;
  ScaleRichViewTextDrawAlwaysUseGlyphs := False;

  Result := TMetafile.Create;
  Result.Width := aWidth;
  Result.Height := aHeight;
  srve.CanUpdate := False;
  srve.UseDrawHyperlinksEvent := True;
  srve.DrawMetafile(aPageNo, Result, False, True, False);
  ScaleRichViewTextDrawAlwaysUseGlyphs := savTextDraw;
  srve.CanUpdate := True;
  srve.UseDrawHyperlinksEvent := False;
end;